* --------------------------------------------------------------------------------
* Schiffsklasse ueberpruefen
* --------------------------------------------------------------------------------

if not [PLAYERSHIP] -> is missile boat
play sample 924
return null
end

* --------------------------------------------------------------------------------
* Start - Script-Version und PageID laden
* --------------------------------------------------------------------------------

$ScriptVersion = get global variable: name= "adv.missile.launcher.version"
[PLAYERSHIP] -> set local variable: name= "adv.missile.launcher.install.version" value= $ScriptVersion

$PageID = get global variable: name= "adv.missile.launcher.text.id"

* --------------------------------------------------------------------------------
* Hauptmenue
* --------------------------------------------------------------------------------

Main :

$Title = read text: page= $PageID id= 1000
$Description = read text: page= $PageID id= 1001
$Array.Menu = create custom menu array

$Config = 1
while $Config <= 4

$MenuItem = sprintf: pageid= $PageID textid= 1002 , $Config , null , null , null , null
add custom menu heading to array $Array.Menu : title= $MenuItem

$TurretMax = [PLAYERSHIP] -> get number of turrets

$VariableGet = "adv.missile.launcher.config." + $Config
$Array.Config = [PLAYERSHIP] -> get local variable: name= $VariableGet

skip if $Array.Config
$Array.Config = array alloc: size= $TurretMax

$Turret = 0
while $Turret < $TurretMax
if [PLAYERSHIP] -> can turret $Turret fire missiles
$Array.Config.Turret = $Array.Config [ $Turret ]
if $Array.Config.Turret
$Missile = $Array.Config.Turret [ 0 ]
$MissileBarrage = $Array.Config.Turret [ 1 ]
$Missile = sprintf: pageid= $PageID textid= 1003 , $Turret , $Missile , null , null , null
$MissileBarrage = sprintf: pageid= $PageID textid= 1010 , $MissileBarrage , null , null , null , null
$MenuItem = create text for custom menu , left= $Missile , right= $MissileBarrage
$ReturnValue = create new array , arguments= "CHANGE" , $Config , $Turret , null , null
add custom menu item to array $Array.Menu : text= $MenuItem returnvalue= $ReturnValue
else
$MenuItem = read text: page= $PageID id= 1011
$MenuItem = sprintf: pageid= $PageID textid= 1003 , $Turret , $MenuItem , null , null , null
$ReturnValue = create new array , arguments= "CHANGE" , $Config , $Turret , null , null
add custom menu item to array $Array.Menu : text= $MenuItem returnvalue= $ReturnValue
end
end
inc $Turret =
end

inc $Config =
end

add section to custom menu: $Array.Menu

$MenuItem = read text: page= $PageID id= 1004
add custom menu item to array $Array.Menu : text= $MenuItem returnvalue= "RESET"

$ShipName = [PLAYERSHIP] -> get name
$ShipID = [PLAYERSHIP] -> get ID code
$ShipID = sprintf: pageid= $PageID textid= 10007 , $ShipID , null , null , null , null
$ShipName = $ShipName + " " + $ShipID
add custom menu info line to array $Array.Menu : text= $ShipName

$Return = open custom menu: title= $Title description= $Description option array= $Array.Menu

if is datatype[ $Return ] == DATATYPE_ARRAY

$Config = $Return [ 1 ]
$Turret = $Return [ 2 ]
$Return = $Return [ 0 ]

if $Return == "CHANGE"

$Array.Menu = create custom menu array
$MenuItem = read text: page= $PageID id= 1012
add custom menu heading to array $Array.Menu : title= $MenuItem

$Array.Missile = [PLAYERSHIP] -> get compatible missile array
$Array.Missile = sort array $Array.Missile

$While = 0
$WhileMax = size of array $Array.Missile
while $While < $WhileMax
$Missile = $Array.Missile [ $While ]
add custom menu item to array $Array.Menu : text= $Missile returnvalue= $Missile
inc $While =
end

$MenuItem = read text: page= $PageID id= 1011
add custom menu item to array $Array.Menu : text= $MenuItem returnvalue= "NONE"

$Missile = open custom menu: title= $Title description= $Description option array= $Array.Menu

if $Missile == "NONE"
$TurretMax = [PLAYERSHIP] -> get number of turrets
$VariableGet = "adv.missile.launcher.config." + $Config
$Array.Config = [PLAYERSHIP] -> get local variable: name= $VariableGet
if $Array.Config
$Array.Config [ $Turret ] = null
$VariableSet = "adv.missile.launcher.config." + $Config
[PLAYERSHIP] -> set local variable: name= $VariableSet value= $Array.Config
end
end

if is datatype[ $Missile ] == DATATYPE_WARE
$Description = read text: page= $PageID id= 1013
$MissileBarrage = [PLAYERSHIP] -> get user input: type= Var/Number , title= $Description
if is datatype[ $MissileBarrage ] == DATATYPE_INT
if $MissileBarrage >= 1 AND $MissileBarrage <= 10

$TurretMax = [PLAYERSHIP] -> get number of turrets
$VariableGet = "adv.missile.launcher.config." + $Config
$Array.Config = [PLAYERSHIP] -> get local variable: name= $VariableGet
skip if $Array.Config
$Array.Config = array alloc: size= $TurretMax

$Array.Config.Turret = create new array , arguments= $Missile , $MissileBarrage , null , null , null
$Array.Config [ $Turret ] = $Array.Config.Turret

$VariableSet = "adv.missile.launcher.config." + $Config
[PLAYERSHIP] -> set local variable: name= $VariableSet value= $Array.Config

end
end
end

goto label Main

end

else if is datatype[ $Return ] == DATATYPE_STRING

if $Return == "RESET"

$Config = 1
while $Config <= 4
$VariableSet = "adv.missile.launcher.config." + $Config
[PLAYERSHIP] -> set local variable: name= $VariableSet value= null
inc $Config =
end

goto label Main

end

end

* --------------------------------------------------------------------------------

return null